Xjyuk

Let me abuse some Mathematica notation and formulate the following "command":

Show[RegionPlot4D[(Q1 - Q4)^2 < 16 Q3^2 && 
 Q1^2 + 4 Q1 Q2 + 16 Q2 (Q2 + Q3) + 12 Q2 Q4 + Q4^2 < 
 4 Q2 + 2 Q1 Q4 && Q1 > 0 && Q2 > 0 && Q3 > 0 && Q4 > 0, Q1, 0, 
 6/61, Q2, 0, 2/9, Q3, 0, 1/32, Q4, 0, 1/6], 
 RegionPlot4D[
 Q4 > 0 && Q2 > 0 && Q3 > 0 && Q1 + 4 (Q2 + Q3) + 3 Q4 < 1 && 
 4 Q2 + 9 Q4 < Q1, Q1, 0, 6/61, Q2, 0, 2/9, Q3, 0, 1/32, Q4, 
 0, 1/6], 
 RegionPlot4D[
 Q4 > 0 && Q2 > 0 && Q3 > 0 && Q1 + 4 (Q2 + Q3) + 3 Q4 < 1 && 
 2 (Q2 + Q3) + 3 Q4 < Q1, Q1, 0, 6/61, Q2, 0, 2/9, Q3, 0, 
 1/32, Q4, 0, 1/6]]

(Of course, there is a RegionPlot3D command, but no RegionPlot4D one.)

Can this be processed/interpreted in some manner? (use of coloring,...)

Also, these three "RegionPlot"s could be considered individually (challenging enough).

These pertain to certain quantum-information-theoretic problems concerned with probabilities of (bound) entanglement.

The problem as put is very much a direct 4D analogue of the 3D problem

Labeling distinct objects produced by Show[RegionPlot3D's]

that kglr answered. So, perhaps I should just try fixing (in various ways) one of the four coordinates and approaching the problem in the very same manner as there. (In fact, the constraints are set up in the same order both times, with the first one each times being the "PPT" one. Incidentally, the "PPT" body should be convex, but not the other two.)

You can define a 4D region with

R = ImplicitRegion[(Q1 - Q4)^2 < 16 Q3^2 && 
 Q1^2 + 4 Q1 Q2 + 16 Q2 (Q2 + Q3) + 12 Q2 Q4 + Q4^2 < 
 4 Q2 + 2 Q1 Q4 && Q1 > 0 && Q2 > 0 && Q3 > 0 && Q4 > 0,
 Q1, Q2, Q3, Q4]

and then check for region membership of any point. For example, make a list of lots of points in 4D and pick out those that lie inside of R:

P = Select[Tuples[Range[0, 1/4, 1/128], 4], Element[#, R] &];
Length[P]
(* 84579 *)

These can be plotted in many ways, for example by projecting out the fourth dimension and using only the first, second, third dimension as coordinate axes:

ListPointPlot3D[P[[All, 1, 2, 3]]]

For a convex set, you can construct the convex hull in 3D for such a projection, for better visibility than the point cloud:

ConvexHullMesh[P[[All, 1, 2, 3]], Boxed -> True, Axes -> True]

Using Graphics3D with VertexColors based on the fourth column is much faster than using ListPointPlot3D.

With a smaller version of Roman's P (to stay within my cloud credit limits):

P = Select[Tuples[Range[0, 1/4, 1/64], 4], Element[#, R] &];

Graphics3D[PointSize[Small], Point[P[[All, ;; 3]], 
 VertexColors -> (Hue /@ P[[All, 4]])]] // RepeatedTiming

versus two alternative ways to use ListPointPlot3D:

ListPointPlot3D[Style[#[[;;3]], Hue @ #[[4]]]& /@ P,
 BaseStyle -> PointSize[Small]] // RepeatedTiming

ListPointPlot3D[List /@ P[[All, ;; 3]], 
 PlotStyle -> (Hue /@ P[[All, 4]]), 
 BaseStyle -> PointSize[Small]] // RepeatedTiming