Xjyuk

I have the following code to retrieve the series of a product that has been purchased. We are using a loop because a contact might purchase multiple products.

 %%[IF NOT EMPTY(@PersonAccountId) 
 THEN set @MyWatchesTable = RetrieveSalesforceObjects("My_Watches__c","Product__c","Person_Account__c", "=", @PersonAccountId,"Status__c","=", "Owner") 
 SET @rowCount = RowCount(@MyWatchesTable) 
 IF @rowCount > 0 THEN 
 FOR @counter = 1 to @rowCount DO 
 SET @MyWatchesRow = Row(@MyWatchesTable, @counter) 
 SET @Product = Field(@MyWatchesRow,"Product__c") 
SET @ProductTable = RetrieveSalesforceObjects("Product2","Series__c","Id", "=", @Product)
set @productCount = RowCount(@ProductTable)
set @ProductRow = Row(@ProductTable, @productCount) 
set @Series = Field(@ProductRow, "Series__c") 

]%%
-->
 Product %%=v(@counter)=%% : %%=v(@Product)=%%<br>
 Series %%=v(@productCount)=%% : %%=v(@Series)=%% <br>
 %%[ next @counter ]%% %%[ else ]%% No records found %%[ endif ]%%
<!-- %%[ENDIF]%%-->

I need to use the results of the loop to select the corresponding product checkbox if they own the product.

I wanted to concatenate the loop results

set @OutPutSeries = Concat(@counter, " ", @Product, " ", @productCount, " ", @Series, " ", next @counter)

and then use the the IndexOf to determine if the concatenated result contains one of the products

/* Does it match; ; if no match, output of IndexOf(1,2) will be "0" */ 
if IndexOf(@Series,'Connected') > 0 then 
 Set @OutputSoldConnected = "True"
else 
 Set @OutputSoldConnected = "False"
endif 

Then use the True/False result to prepopulate the checkbox

I have tried to use the indexOf on the @Series variable but it only returns the last result, that is why I thought about concatenating them but it did not work.

If you need to append values to a variable from within a loop, you'll need to remember to include the variable itself during concatenation. Otherwise, you'll simply be "re-setting" the variable after each iteration (i.e., the variable will be set according to the last iteration, only).

For example, this yields only the last result:

%%[
for @counter = 1 to 3 do
 set @series = Concat(@counter, " ")
next @counter
]%%
%%=V(@series)=%%

Output:

3

This, on the other hand, will yield all concatenated values:

%%[
set @series = "" /* initialize outside of loop */

for @counter = 1 to 3 do
 set @series = Concat(@series, @counter, " ") /* include existing value first */
next @counter
]%%
%%=V(@series)=%%

Output:

1 2 3